– ROBÓTICA ESCOLAR –
Proyecto Tecnológico para 4º de ESO “Puertas automatizadas”
Acerca de este proyecto
Este Proyecto Tenológico fue realizado en 4º de ESO del IES Joaquín Romero Murube.
Se trataba de construir una puerta que se abriera mecánicamente tras activar algún dispositivo, que permaneciera abierta un tiempo y se volviera a cerrar por sí sola. Podía además ir acompañada de señalización tanto de luces como de sonido.
Propuesta de trabajo
Enunciado de la propuesta
Diseñar y construir una puerta cuya apertura y cierre se realice mediante automatismos.
Llamaremos al proyecto “Puertas automatizadas“.
Condiciones de la propuesta
- Se podrá elegir cualquier tipo de puerta, como por ejemplo dos puertas deslizantes hacia los lados, una puerta que se desliza hacia un lado, puerta de dos piezas plegable hacia arriba o cualquier otro tipo de puerta de características similares.
- El mecanismo de apertura y cierre queda a libre elección.
- Todos los circuitos estarán gobernados por una tarjeta controladora PICAXE CHI035A.
- Las puertas por defecto estarán cerradas.
- Un pulsador servirá para abrir la puerta. Puede cambiarse por algún sensor de presencia.
- La puerta se cerrará automáticamente pasados 10 segundos (caso de no estar pulsado o activado el sensor de apertura).
- La puerta detendrá automáticamente su movimiento al terminar de abrirse o cerrarse. Podrán usarse para ello finales de carrera o interruptores magnéticos (Reed).
- El hueco de la puerta estará comprendido entre 20×15 y 30×20 centímetros.
- Ampliación: Un LED rojo y otro verde indicarán si la puerta está abierta o cerrada.
- Ampliación: Se activará un zumbador mientras se abre o se cierra la puerta.
- Todo el proyecto se montará sobre una tabla de madera de 50cm x 20cm.
Se proporciona esquema, circuito y programa modelo.
Esquema del circuito
Croquis de montaje del circuito
Programa modelo
1. Puertas automatizadas. Programa modelo de referencia
- Microcontrolador:
- PICAXE-18M2
- Tarjeta controladora:
- “Proyectos PICAXE-18 de alta potencia (CHI035A)”
- Sensores:
- Pulsador y finales de carrera en B.2, B.5 y B.6 respectivamente
- Actuadores:
- Motor en B.4 y B.5 . LED verde en B.0 y LED rojo en B.1
- Función:
- Por defecto la puerta está cerrada (LED rojo encendido)
- Si presionamos pulsador empieza a abrirse (LED verde parpadea)
- La puerta termina de abrirse (LED verde encendido) y se esperan 10 segundos.
- La puerta empieza a cerrarse (LED rojo parpadea).
- Tras cerrarse volvemos a estar en la situación inicial.
- Código del programa:
;--------- INFORMACIÓN ----------
; Nombre : 0-puerta-modelo.bas
; Autor : Dep. Tecnología - IES J. Romero Murube
; Micro : PICAXE-18M2
; Tarjeta : CHI035A
; Entradas: C.1 -> Pulsador/FDC para abrir la puerta
; C.5 -> FDC1 puerta totalmente cerrada
; C.6 -> FDC2 puerta totalmente abierta
; Salidas : B.0 <- LED verde
; B.1 <- LED rojo
; B.4 y B.5 <- Motor
; Función : PROYECTO "Puerta automatizada" - TEC 4ºESO 2013-2014
; CERRADA -> estado_puerta = 0
; Puerta cerrada; LED rojo encendido
; Pulsación (C.2) para abrir
; ABRIÉNDOSE -> estado_puerta = 2
; Se abre la puerta; LED verde parpadea
; ABIERTA -> estado_puerta = 1
; Puerta abierta; LED verde encendido
; Pausa de 10 segundos
; CERRÁNDOSE -> estado_puerta = 3
; Se cierra la puerta; LED rojo parpadea
; NOTA1 : Cada grupo puede personalizar su programa
; NOTA2 : Se utilizan dos tareas simultáneas START0 y START1
; En START0 se comprueban sensores y se controla motor
; En START1 se controlan los LED según "estado_puerta"
;--------------------------------
start0:
;------ INICIALIZACIÓN 0 --------
symbol estado_puerta = b0
estado_puerta = 0 ;Puerta inicialmente cerrada
;--------------------------------
;------ BUCLE PRINCIPAL 0 -------
do
;Se comprueba pulsación para abrir
if pinC.1 is on then ;SI se pulsa ENTONCES
estado_puerta = 2 ; (ABRIÉNDOSE)
high B.4 ; motor en marcha (abrir)
low B.5 ; para abrir la puerta;
pause 5000 ; al menos 5s abriendo
endif ;(FIN del SI-ENTONCES)
;Se comprueba FDC2 de puerta abierta totalmente
if pinC.6 is on then ;SI FDC2 pulsado ENCONTES
estado_puerta = 1 ; (ABIERTA)
low B.4 ; se para motor
low B.5
pause 10000 ; y se esperan 10s;
estado_puerta = 3 ; (CERRÁNDOSE)
low B.4 ; motor en marcha (cerrar)
high B.5 ; para cerra la puerta;
pause 5000 ; al menos 5 segundos
endif ;(FIN del SI-ENTONCES)
;Se comprueba FDC1 de puerta cerrada totalmente
if pinC.5 is on then ;SI FDC1 pulsado ENCONTES
estado_puerta = 0 ; (CERRADA)
low B.4 ; se para motor
low B.5
endif ;(FIN del SI-ENTONCES)
loop
;--------------------------------
start1:
;------ BUCLE PRINCIPAL 1 -------
do
select case estado_puerta
case 0 ;PUERTA CERRADA
low B.0 ; - led verde apagado
high B.1 ; - led rojo encendido
case 1 ;PUERTA ABIERTA
high B.0 ; - led verde encendido
low B.1 ; - led rojo apagado
case 2 ;PUERTA ABRIENDOSE
low B.1 ; - led rojo apagado
high B.0 ; - led verde parpadeando !!!
pause 300
low B.0
pause 300
case 3 ;PUERTA CERRANDOSE
low B.0 ; - led verde apagado
high B.1 ; - led rojo Parpadeando !!!
pause 300
low B.1
pause 300
end select
loop
;--------------------------------
;--------- SUBRUTINAS -----------
;--------------------------------
Vídeo resumen
En este vídeo se muestran resumidos todos los 7 modelos de puerta que se construyeron:
- Puerta con apertura abatible lateral.
- Doble puerta lateral deslizante.
- Doble puerta plegable hacia arriba.
- Puerta deslizante hacia arriba.
- Doble puerta lateral colgante.
- Puerta abatible hacia arriba y atrás.
- Puerta enrollable hacia arriba.
Francisco M. Ruiz Segura
Profesor de Tecnología en EESS
robotica-escolar-eso.blogspot.com